System: POV-Ray for Windows v3.5b2, Windows NT4 sp6, AMD Athlon 1GHz,
256 megs SDRam

I know radiosity is considered experimental, but I thought I would
report my observation.

With recursion_limit 2 or higher a simple ambient sphere in a box
produces a very strange illumination.

If you run the appended script you will see very distinct vertical and
horizontal bright bands on the surfaces, of the same width as the
sphere.

Reducing the error_bound makes the edges of the bands sharper,
increasing count makes them more even.

Using a single box as the container gives much wider illuminated bands,
less easy to see.

The script gives an identical result with MegaPov 0.7.

Bye for now,
	Mike Andrews.

// start of script
// +w160 +h120 -a

global_settings { 
  max_trace_level 5
  assumed_gamma 1
  ambient_light 1
#if(1)
  radiosity {
    pretrace_start 8/image_width
    pretrace_end   4/image_width
    count 200
    error_bound 0.2
    recursion_limit 2
  }
#end
}

camera {
  location  <4, 3.0, -4.0>*7
  direction 1.7*z  
  right     x*image_width/image_height
  look_at   <-5, -10, 10> 
}

// light source
sphere { 0, 2 
  pigment { rgb 10 } 
  finish { ambient 1 diffuse 0 } 
  translate <-5, -10, 10> 
}

// container
#declare A = -<15,25,40>;
#declare B = <40,40,25>;
     
box { A-1+x,B+1-x inverse 
  pigment { rgb <1,.6,.2> } 
  finish { ambient 0 diffuse 0.8 } 
}
box { A-1+y,B+1-y inverse 
  pigment { rgb <.6,.2,1> } 
  finish { ambient 0 diffuse 0.8 } 
}
box { A-1+z,B+1-z inverse 
  pigment { rgb <.2,1,.6> } 
  finish { ambient 0 diffuse 0.8 } 
}

// end of script

Post a reply to this message